An Alternate Universe of the Cube

I like Bruce's idea very much and one definitely wants to hack up a simulation of this puzzle (actually making a real one seems rather difficult).


What I have done so far is hack up the corner turning Oh-cube and I made a short video showing the 5-spot pattern:

Corner Turning Cube

To contact the admin of this site send emails to: cubexyz at gmail dot com

Hi Bruce,

Cube orientations have a parity (given by the parity of the permutation of the 6 faces). The 27 cubelets locations split into 2 sets according to a checkerboard colouring. I think that the only way to move a cubelet from one set to the other is by a move with an odd reorientation parity. Therefore the orientation of any cubelet has even parity if it is in a location of the same checkerboard colour as its home location, and odd if it is in a location with a different colour. This alone reduces the number of positions the puzzle has by 2²⁷. Solving the puzzle in a position reoriented by a quarter turn is already ruled out by these constraints.

The parity of the cubelet permutation is even (a quarter turn of a 2x2x2 is two 4-cycles, an even permutation, and such quarter turns generate all possible moves). This gives another factor of 2.

The number of positions is therefore at most 27!*24²⁷/2²⁸ = 7.4790e+56

The number you give is one third of that. If your Gap model is correct, this means that there is some kind of twist invariant as well. It's a tricky one.

Define the twist of a cubelet in one of the sets of locations as 0 if the U/D colours are in the U/D facelets, 1 if they are in the R/L facelets, 2 if they are in the F/B facelets. The twist of a cubelet in the other set of locations is similar but with 1 and 2 swapped.

A quarter turn of a 2x2x2 subcube consists of two 4-cycles. A turn around the U/D axis will leave all cubelets in the same orientation. A quarter turn around one of the other axes will increment the orientations in one cycle and decrement those on the other, and therefore still leave the total twist the same modulo 3.

This also shows that it is impossible to solve the puzzle in a reoriented position 120 degrees rotated about a corner. All the cubelets on one set will have to be twisted +1, and in the other set -1. Since there are 14 in one set and 13 in the other, the total twist would have to change.

Jaap
Jaap's Puzzle Page: http://www.jaapsch.net/puzzles/

Thanks, Jaap, for analyzing the invariants of the puzzle.

If it's useful to anyone, my GAP definitions are found below.

I used 6 consecutive numbers for each cubie. The order of the facelets is U,D,L,R,F,B. The first cubie is ULB. The rest of the U layer cubies follow in the order UB, UBR, UL, U, UR, UFL, UF, and URF. This is followed by the middle (horizontal) layer, and finally the bottom layer.

To simplify the definitions, I defined functions that generate "moves" for 3-cycling whole layers. I then only needed to explicitly define 3 per permutations of the puzzle facelets (raw numeric definitions). These "moves" were "U1" (equivalent to performing U on a Rubik's Cube) and "L1" (equivalent to performing L on a Rubik's cube), and "cyu" (similar to U1, except only cycles four cubies on the U layer). From "U1" and "L1" and the layer 3-cycles I could make definitions for whole cube rotations. Conjugating "cyu" by a layer shifter allowed defining "cyd" which cycles the 4 cubies below the "cyu" cubies. Combining "cyu" and "cyd" then gives one of the basic moves of the puzzle. Then conjugating by whole cube rotations allows defining all the other basic moves of the puzzle.

The actual code is:

U1a := (1,13,49,37)(2,14,50,38)(7,31,43,19)(8,32,44,20);
U1b := (9,36,46,23)(10,35,45,24)(27,30,28,29);
U1c := (3,18,52,41)(12,34,47,21)(6,16,53,39);
U1d := (4,17,51,42)(11,33,48,22)(5,15,54,40);
U1 := U1a*U1b*U1c*U1d;

MakeV1 := function ()
  local i, g;
  g := ();
  i := 1;
  while i <= 54 do
    g := g*(i, i+108, i+54);
    i := i + 1;
  od;
  return g;
end;
V1 := MakeV1 ();

E1 := V1*U1*(V1^-1);
D1 := (V1^-1)*U1*V1;
y := U1*E1*D1;
y2 := y*y;
y3 := y2*y;

L1a := (3,39,147,111)(4,40,148,112)(21,93,129,57)(22,94,130,58);
L1b := (1,41,146,114)(19,95,128,60)(6,37,149,110);
L1c := (5,38,150,109)(20,96,127,59)(2,42,145,113);
L1d := (23,92,132,55)(73,77,74,78)(24,91,131,56);
L1 := L1a*L1b*L1c*L1d;

MakeH1 := function ()
  local i, j, g;
  g := ();
  i := 0;
  while i <= 144 do
    j := 1;
    while j <= 6 do
      g := g*(i+j, i+j+12, i+j+6);
      j := j + 1;
    od;
    i := i + 18;
  od;
  return g;
end;
H1 := MakeH1 ();

M1 := H1*L1*(H1^-1);
R1 := (H1^-1)*L1*H1;
x3 := L1*M1*R1;
x2 := x3*x3;
x := x2*x3;

cyu := (25,31,49,43)(26,32,50,44)(27,36,52,47)(28,35,51,48)(29,33,54,46)(30,34,53,45);
cyd := V1*cyu*(V1^-1);
cy := cyu*cyd;
cx := y3*x3*cy*x*y;

URFcy := cy;
UFLcy := y3*cy*y;
ULBcy := y2*cy*y2;
UBRcy := y*cy*y3;
DRBcy := x2*cy*x2;
DBLcy := x2*y3*cy*y*x2;
DLFcy := x2*y2*cy*y2*x2;
DFRcy := x2*y*cy*y3*x2;

URFcx := cx;
UFLcx := y3*cx*y;
ULBcx := y2*cx*y2;
UBRcx := y*cx*y3;
DRBcx := x2*cx*x2;
DBLcx := x2*y3*cx*y*x2;
DLFcx := x2*y2*cx*y2*x2;
DFRcx := x2*y*cx*y3*x2;

G := Group (URFcy,UFLcy,ULBcy,UBRcy,DRBcy,DBLcy,DLFcy,DFRcy,
  URFcx,UFLcx,ULBcx,UBRcx,DRBcx,DBLcx,DLFcx,DFRcx);

This took me by surprise. I never would have thought there would be enough clearance to rotate the 2x2x2 block on a real puzzle. Amazing work! I must post some patterns later.

To contact the admin of this site send emails to: cubexyz at gmail dot com